Imported Upstream version 7.1.614
[packages/dc3dd.git] / m4 / stdint.m4
1 # stdint.m4 serial 31
2 dnl Copyright (C) 2001-2008 Free Software Foundation, Inc.
3 dnl This file is free software; the Free Software Foundation
4 dnl gives unlimited permission to copy and/or distribute it,
5 dnl with or without modifications, as long as this notice is preserved.
6
7 dnl From Paul Eggert and Bruno Haible.
8 dnl Test whether <stdint.h> is supported or must be substituted.
9
10 AC_DEFUN([gl_STDINT_H],
11 [
12   AC_PREREQ(2.59)dnl
13
14   dnl Check for long long int and unsigned long long int.
15   AC_REQUIRE([AC_TYPE_LONG_LONG_INT])
16   if test $ac_cv_type_long_long_int = yes; then
17     HAVE_LONG_LONG_INT=1
18   else
19     HAVE_LONG_LONG_INT=0
20   fi
21   AC_SUBST([HAVE_LONG_LONG_INT])
22   AC_REQUIRE([AC_TYPE_UNSIGNED_LONG_LONG_INT])
23   if test $ac_cv_type_unsigned_long_long_int = yes; then
24     HAVE_UNSIGNED_LONG_LONG_INT=1
25   else
26     HAVE_UNSIGNED_LONG_LONG_INT=0
27   fi
28   AC_SUBST([HAVE_UNSIGNED_LONG_LONG_INT])
29
30   dnl Check for <inttypes.h>.
31   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_inttypes_h.
32   if test $ac_cv_header_inttypes_h = yes; then
33     HAVE_INTTYPES_H=1
34   else
35     HAVE_INTTYPES_H=0
36   fi
37   AC_SUBST([HAVE_INTTYPES_H])
38
39   dnl Check for <sys/types.h>.
40   dnl AC_INCLUDES_DEFAULT defines $ac_cv_header_sys_types_h.
41   if test $ac_cv_header_sys_types_h = yes; then
42     HAVE_SYS_TYPES_H=1
43   else
44     HAVE_SYS_TYPES_H=0
45   fi
46   AC_SUBST([HAVE_SYS_TYPES_H])
47
48   gl_CHECK_NEXT_HEADERS([stdint.h])
49   if test $ac_cv_header_stdint_h = yes; then
50     HAVE_STDINT_H=1
51   else
52     HAVE_STDINT_H=0
53   fi
54   AC_SUBST([HAVE_STDINT_H])
55
56   dnl Now see whether we need a substitute <stdint.h>.
57   if test $ac_cv_header_stdint_h = yes; then
58     AC_CACHE_CHECK([whether stdint.h conforms to C99],
59       [gl_cv_header_working_stdint_h],
60       [gl_cv_header_working_stdint_h=no
61        AC_COMPILE_IFELSE([
62          AC_LANG_PROGRAM([[
63 #define __STDC_LIMIT_MACROS 1 /* to make it work also in C++ mode */
64 #define __STDC_CONSTANT_MACROS 1 /* to make it work also in C++ mode */
65 #define _GL_JUST_INCLUDE_SYSTEM_STDINT_H 1 /* work if build isn't clean */
66 #include <stdint.h>
67 /* Dragonfly defines WCHAR_MIN, WCHAR_MAX only in <wchar.h>.  */
68 #if !(defined WCHAR_MIN && defined WCHAR_MAX)
69 #error "WCHAR_MIN, WCHAR_MAX not defined in <stdint.h>"
70 #endif
71 ]
72 gl_STDINT_INCLUDES
73 [
74 #ifdef INT8_MAX
75 int8_t a1 = INT8_MAX;
76 int8_t a1min = INT8_MIN;
77 #endif
78 #ifdef INT16_MAX
79 int16_t a2 = INT16_MAX;
80 int16_t a2min = INT16_MIN;
81 #endif
82 #ifdef INT32_MAX
83 int32_t a3 = INT32_MAX;
84 int32_t a3min = INT32_MIN;
85 #endif
86 #ifdef INT64_MAX
87 int64_t a4 = INT64_MAX;
88 int64_t a4min = INT64_MIN;
89 #endif
90 #ifdef UINT8_MAX
91 uint8_t b1 = UINT8_MAX;
92 #else
93 typedef int b1[(unsigned char) -1 != 255 ? 1 : -1];
94 #endif
95 #ifdef UINT16_MAX
96 uint16_t b2 = UINT16_MAX;
97 #endif
98 #ifdef UINT32_MAX
99 uint32_t b3 = UINT32_MAX;
100 #endif
101 #ifdef UINT64_MAX
102 uint64_t b4 = UINT64_MAX;
103 #endif
104 int_least8_t c1 = INT8_C (0x7f);
105 int_least8_t c1max = INT_LEAST8_MAX;
106 int_least8_t c1min = INT_LEAST8_MIN;
107 int_least16_t c2 = INT16_C (0x7fff);
108 int_least16_t c2max = INT_LEAST16_MAX;
109 int_least16_t c2min = INT_LEAST16_MIN;
110 int_least32_t c3 = INT32_C (0x7fffffff);
111 int_least32_t c3max = INT_LEAST32_MAX;
112 int_least32_t c3min = INT_LEAST32_MIN;
113 int_least64_t c4 = INT64_C (0x7fffffffffffffff);
114 int_least64_t c4max = INT_LEAST64_MAX;
115 int_least64_t c4min = INT_LEAST64_MIN;
116 uint_least8_t d1 = UINT8_C (0xff);
117 uint_least8_t d1max = UINT_LEAST8_MAX;
118 uint_least16_t d2 = UINT16_C (0xffff);
119 uint_least16_t d2max = UINT_LEAST16_MAX;
120 uint_least32_t d3 = UINT32_C (0xffffffff);
121 uint_least32_t d3max = UINT_LEAST32_MAX;
122 uint_least64_t d4 = UINT64_C (0xffffffffffffffff);
123 uint_least64_t d4max = UINT_LEAST64_MAX;
124 int_fast8_t e1 = INT_FAST8_MAX;
125 int_fast8_t e1min = INT_FAST8_MIN;
126 int_fast16_t e2 = INT_FAST16_MAX;
127 int_fast16_t e2min = INT_FAST16_MIN;
128 int_fast32_t e3 = INT_FAST32_MAX;
129 int_fast32_t e3min = INT_FAST32_MIN;
130 int_fast64_t e4 = INT_FAST64_MAX;
131 int_fast64_t e4min = INT_FAST64_MIN;
132 uint_fast8_t f1 = UINT_FAST8_MAX;
133 uint_fast16_t f2 = UINT_FAST16_MAX;
134 uint_fast32_t f3 = UINT_FAST32_MAX;
135 uint_fast64_t f4 = UINT_FAST64_MAX;
136 #ifdef INTPTR_MAX
137 intptr_t g = INTPTR_MAX;
138 intptr_t gmin = INTPTR_MIN;
139 #endif
140 #ifdef UINTPTR_MAX
141 uintptr_t h = UINTPTR_MAX;
142 #endif
143 intmax_t i = INTMAX_MAX;
144 uintmax_t j = UINTMAX_MAX;
145
146 #include <limits.h> /* for CHAR_BIT */
147 #define TYPE_MINIMUM(t) \
148   ((t) ((t) 0 < (t) -1 ? (t) 0 : ~ (t) 0 << (sizeof (t) * CHAR_BIT - 1)))
149 #define TYPE_MAXIMUM(t) \
150   ((t) ((t) 0 < (t) -1 ? (t) -1 : ~ (~ (t) 0 << (sizeof (t) * CHAR_BIT - 1))))
151 struct s {
152   int check_PTRDIFF:
153       PTRDIFF_MIN == TYPE_MINIMUM (ptrdiff_t)
154       && PTRDIFF_MAX == TYPE_MAXIMUM (ptrdiff_t)
155       ? 1 : -1;
156   /* Detect bug in FreeBSD 6.0 / ia64.  */
157   int check_SIG_ATOMIC:
158       SIG_ATOMIC_MIN == TYPE_MINIMUM (sig_atomic_t)
159       && SIG_ATOMIC_MAX == TYPE_MAXIMUM (sig_atomic_t)
160       ? 1 : -1;
161   int check_SIZE: SIZE_MAX == TYPE_MAXIMUM (size_t) ? 1 : -1;
162   int check_WCHAR:
163       WCHAR_MIN == TYPE_MINIMUM (wchar_t)
164       && WCHAR_MAX == TYPE_MAXIMUM (wchar_t)
165       ? 1 : -1;
166   /* Detect bug in mingw.  */
167   int check_WINT:
168       WINT_MIN == TYPE_MINIMUM (wint_t)
169       && WINT_MAX == TYPE_MAXIMUM (wint_t)
170       ? 1 : -1;
171
172   /* Detect bugs in glibc 2.4 and Solaris 10 stdint.h, among others.  */
173   int check_UINT8_C:
174         (-1 < UINT8_C (0)) == (-1 < (uint_least8_t) 0) ? 1 : -1;
175   int check_UINT16_C:
176         (-1 < UINT16_C (0)) == (-1 < (uint_least16_t) 0) ? 1 : -1;
177
178   /* Detect bugs in OpenBSD 3.9 stdint.h.  */
179 #ifdef UINT8_MAX
180   int check_uint8: (uint8_t) -1 == UINT8_MAX ? 1 : -1;
181 #endif
182 #ifdef UINT16_MAX
183   int check_uint16: (uint16_t) -1 == UINT16_MAX ? 1 : -1;
184 #endif
185 #ifdef UINT32_MAX
186   int check_uint32: (uint32_t) -1 == UINT32_MAX ? 1 : -1;
187 #endif
188 #ifdef UINT64_MAX
189   int check_uint64: (uint64_t) -1 == UINT64_MAX ? 1 : -1;
190 #endif
191   int check_uint_least8: (uint_least8_t) -1 == UINT_LEAST8_MAX ? 1 : -1;
192   int check_uint_least16: (uint_least16_t) -1 == UINT_LEAST16_MAX ? 1 : -1;
193   int check_uint_least32: (uint_least32_t) -1 == UINT_LEAST32_MAX ? 1 : -1;
194   int check_uint_least64: (uint_least64_t) -1 == UINT_LEAST64_MAX ? 1 : -1;
195   int check_uint_fast8: (uint_fast8_t) -1 == UINT_FAST8_MAX ? 1 : -1;
196   int check_uint_fast16: (uint_fast16_t) -1 == UINT_FAST16_MAX ? 1 : -1;
197   int check_uint_fast32: (uint_fast32_t) -1 == UINT_FAST32_MAX ? 1 : -1;
198   int check_uint_fast64: (uint_fast64_t) -1 == UINT_FAST64_MAX ? 1 : -1;
199   int check_uintptr: (uintptr_t) -1 == UINTPTR_MAX ? 1 : -1;
200   int check_uintmax: (uintmax_t) -1 == UINTMAX_MAX ? 1 : -1;
201   int check_size: (size_t) -1 == SIZE_MAX ? 1 : -1;
202 };
203          ]])],
204          [gl_cv_header_working_stdint_h=yes])])
205   fi
206   if test "$gl_cv_header_working_stdint_h" = yes; then
207     STDINT_H=
208   else
209     dnl Check for <sys/inttypes.h>, and for
210     dnl <sys/bitypes.h> (used in Linux libc4 >= 4.6.7 and libc5).
211     AC_CHECK_HEADERS([sys/inttypes.h sys/bitypes.h])
212     if test $ac_cv_header_sys_inttypes_h = yes; then
213       HAVE_SYS_INTTYPES_H=1
214     else
215       HAVE_SYS_INTTYPES_H=0
216     fi
217     AC_SUBST([HAVE_SYS_INTTYPES_H])
218     if test $ac_cv_header_sys_bitypes_h = yes; then
219       HAVE_SYS_BITYPES_H=1
220     else
221       HAVE_SYS_BITYPES_H=0
222     fi
223     AC_SUBST([HAVE_SYS_BITYPES_H])
224
225     dnl Check for <wchar.h> (missing in Linux uClibc when built without wide
226     dnl character support).
227     AC_CHECK_HEADERS_ONCE([wchar.h])
228
229     gl_STDINT_TYPE_PROPERTIES
230     STDINT_H=stdint.h
231   fi
232   AC_SUBST(STDINT_H)
233 ])
234
235 dnl gl_STDINT_BITSIZEOF(TYPES, INCLUDES)
236 dnl Determine the size of each of the given types in bits.
237 AC_DEFUN([gl_STDINT_BITSIZEOF],
238 [
239   dnl Use a shell loop, to avoid bloating configure, and
240   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
241   dnl   config.h.in,
242   dnl - extra AC_SUBST calls, so that the right substitutions are made.
243   m4_foreach_w([gltype], [$1],
244     [AH_TEMPLATE([BITSIZEOF_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]),
245        [Define to the number of bits in type ']gltype['.])])
246   for gltype in $1 ; do
247     AC_CACHE_CHECK([for bit size of $gltype], [gl_cv_bitsizeof_${gltype}],
248       [AC_COMPUTE_INT([result], [sizeof ($gltype) * CHAR_BIT],
249          [$2
250 #include <limits.h>], [result=unknown])
251        eval gl_cv_bitsizeof_${gltype}=\$result
252       ])
253     eval result=\$gl_cv_bitsizeof_${gltype}
254     if test $result = unknown; then
255       dnl Use a nonempty default, because some compilers, such as IRIX 5 cc,
256       dnl do a syntax check even on unused #if conditions and give an error
257       dnl on valid C code like this:
258       dnl   #if 0
259       dnl   # if  > 32
260       dnl   # endif
261       dnl   #endif
262       result=0
263     fi
264     GLTYPE=`echo "$gltype" | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
265     AC_DEFINE_UNQUOTED([BITSIZEOF_${GLTYPE}], [$result])
266     eval BITSIZEOF_${GLTYPE}=\$result
267   done
268   m4_foreach_w([gltype], [$1],
269     [AC_SUBST([BITSIZEOF_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))])
270 ])
271
272 dnl gl_CHECK_TYPES_SIGNED(TYPES, INCLUDES)
273 dnl Determine the signedness of each of the given types.
274 dnl Define HAVE_SIGNED_TYPE if type is signed.
275 AC_DEFUN([gl_CHECK_TYPES_SIGNED],
276 [
277   dnl Use a shell loop, to avoid bloating configure, and
278   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
279   dnl   config.h.in,
280   dnl - extra AC_SUBST calls, so that the right substitutions are made.
281   m4_foreach_w([gltype], [$1],
282     [AH_TEMPLATE([HAVE_SIGNED_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]),
283        [Define to 1 if ']gltype[' is a signed integer type.])])
284   for gltype in $1 ; do
285     AC_CACHE_CHECK([whether $gltype is signed], [gl_cv_type_${gltype}_signed],
286       [AC_COMPILE_IFELSE(
287          [AC_LANG_PROGRAM([$2[
288             int verify[2 * (($gltype) -1 < ($gltype) 0) - 1];]])],
289          result=yes, result=no)
290        eval gl_cv_type_${gltype}_signed=\$result
291       ])
292     eval result=\$gl_cv_type_${gltype}_signed
293     GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
294     if test "$result" = yes; then
295       AC_DEFINE_UNQUOTED([HAVE_SIGNED_${GLTYPE}], 1)
296       eval HAVE_SIGNED_${GLTYPE}=1
297     else
298       eval HAVE_SIGNED_${GLTYPE}=0
299     fi
300   done
301   m4_foreach_w([gltype], [$1],
302     [AC_SUBST([HAVE_SIGNED_]translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_]))])
303 ])
304
305 dnl gl_INTEGER_TYPE_SUFFIX(TYPES, INCLUDES)
306 dnl Determine the suffix to use for integer constants of the given types.
307 dnl Define t_SUFFIX for each such type.
308 AC_DEFUN([gl_INTEGER_TYPE_SUFFIX],
309 [
310   dnl Use a shell loop, to avoid bloating configure, and
311   dnl - extra AH_TEMPLATE calls, so that autoheader knows what to put into
312   dnl   config.h.in,
313   dnl - extra AC_SUBST calls, so that the right substitutions are made.
314   m4_foreach_w([gltype], [$1],
315     [AH_TEMPLATE(translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX],
316        [Define to l, ll, u, ul, ull, etc., as suitable for
317         constants of type ']gltype['.])])
318   for gltype in $1 ; do
319     AC_CACHE_CHECK([for $gltype integer literal suffix],
320       [gl_cv_type_${gltype}_suffix],
321       [eval gl_cv_type_${gltype}_suffix=no
322        eval result=\$gl_cv_type_${gltype}_signed
323        if test "$result" = yes; then
324          glsufu=
325        else
326          glsufu=u
327        fi
328        for glsuf in "$glsufu" ${glsufu}l ${glsufu}ll ${glsufu}i64; do
329          case $glsuf in
330            '')  gltype1='int';;
331            l)   gltype1='long int';;
332            ll)  gltype1='long long int';;
333            i64) gltype1='__int64';;
334            u)   gltype1='unsigned int';;
335            ul)  gltype1='unsigned long int';;
336            ull) gltype1='unsigned long long int';;
337            ui64)gltype1='unsigned __int64';;
338          esac
339          AC_COMPILE_IFELSE(
340            [AC_LANG_PROGRAM([$2[
341               extern $gltype foo;
342               extern $gltype1 foo;]])],
343            [eval gl_cv_type_${gltype}_suffix=\$glsuf])
344          eval result=\$gl_cv_type_${gltype}_suffix
345          test "$result" != no && break
346        done])
347     GLTYPE=`echo $gltype | tr 'abcdefghijklmnopqrstuvwxyz ' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ_'`
348     eval result=\$gl_cv_type_${gltype}_suffix
349     test "$result" = no && result=
350     eval ${GLTYPE}_SUFFIX=\$result
351     AC_DEFINE_UNQUOTED([${GLTYPE}_SUFFIX], $result)
352   done
353   m4_foreach_w([gltype], [$1],
354     [AC_SUBST(translit(gltype,[abcdefghijklmnopqrstuvwxyz ],[ABCDEFGHIJKLMNOPQRSTUVWXYZ_])[_SUFFIX])])
355 ])
356
357 dnl gl_STDINT_INCLUDES
358 AC_DEFUN([gl_STDINT_INCLUDES],
359 [[
360   /* BSD/OS 4.0.1 has a bug: <stddef.h>, <stdio.h> and <time.h> must be
361      included before <wchar.h>.  */
362   #include <stddef.h>
363   #include <signal.h>
364   #if HAVE_WCHAR_H
365   # include <stdio.h>
366   # include <time.h>
367   # include <wchar.h>
368   #endif
369 ]])
370
371 dnl gl_STDINT_TYPE_PROPERTIES
372 dnl Compute HAVE_SIGNED_t, BITSIZEOF_t and t_SUFFIX, for all the types t
373 dnl of interest to stdint.in.h.
374 AC_DEFUN([gl_STDINT_TYPE_PROPERTIES],
375 [
376   gl_STDINT_BITSIZEOF([ptrdiff_t sig_atomic_t size_t wchar_t wint_t],
377     [gl_STDINT_INCLUDES])
378   gl_CHECK_TYPES_SIGNED([sig_atomic_t wchar_t wint_t],
379     [gl_STDINT_INCLUDES])
380   gl_cv_type_ptrdiff_t_signed=yes
381   gl_cv_type_size_t_signed=no
382   gl_INTEGER_TYPE_SUFFIX([ptrdiff_t sig_atomic_t size_t wchar_t wint_t],
383     [gl_STDINT_INCLUDES])
384 ])
385
386 dnl Autoconf >= 2.61 has AC_COMPUTE_INT built-in.
387 dnl Remove this when we can assume autoconf >= 2.61.
388 m4_ifdef([AC_COMPUTE_INT], [], [
389   AC_DEFUN([AC_COMPUTE_INT], [_AC_COMPUTE_INT([$2],[$1],[$3],[$4])])
390 ])
391
392 # Hey Emacs!
393 # Local Variables:
394 # indent-tabs-mode: nil
395 # End: